qbittorrent's torrent creator tool

[res0r9lm2]

qbittorrent can only create torrents with piece size up to 4MiB. I made patch to be able to create piece sizes 8MiB and 16MiB as well because some trackers limit the size of torrent file and if data you are trying to upload is large torrent gets rejected.

qbittorrent-2.9.2.ebuild

Code: Select all

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/qbittorrent-2.9.2.ebuild,v 1.1 2011/10/29 16:50:52 hwoarang Exp $

EAPI="2"
PYTHON_DEPEND="2"

inherit python qt4-r2 versionator

MY_P="${P/_/}"
DESCRIPTION="BitTorrent client in C++ and Qt"
HOMEPAGE="http://www.qbittorrent.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="dbus +X geoip"

QT_MIN="4.6.1"
# boost version so that we always have thread support
CDEPEND="net-libs/rb_libtorrent
   >=x11-libs/qt-core-${QT_MIN}:4
   X? ( >=x11-libs/qt-gui-${QT_MIN}:4 )
   dbus? ( >=x11-libs/qt-dbus-${QT_MIN}:4 )
   dev-libs/boost"
DEPEND="${CDEPEND}
   dev-util/pkgconfig"
RDEPEND="${CDEPEND}
   geoip? ( dev-libs/geoip )"

DOCS="AUTHORS Changelog NEWS README TODO"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
   python_set_active_version 2
   python_pkg_setup
}

src_prepare() {
   epatch "${FILESDIR}/${PN}-torrent-creator-tool.patch"
   # Respect LDFLAGS
   sed -i -e 's/-Wl,--as-needed/$(LDFLAGS)/g' src/src.pro
   qt4-r2_src_prepare
}

src_configure() {
   local myconf
   use X         || myconf+=" --disable-gui"
   use geoip     || myconf+=" --disable-geoip-database"
   use dbus      || myconf+=" --disable-qt-dbus"

   # slotted boost detection, bug #309415
   BOOST_PKG="$(best_version ">=dev-libs/boost-1.34.1")"
   BOOST_VER="$(get_version_component_range 1-2 "${BOOST_PKG/*boost-/}")"
   BOOST_VER="$(replace_all_version_separators _ "${BOOST_VER}")"
   myconf+=" --with-libboost-inc=/usr/include/boost-${BOOST_VER}"

   # econf fails, since this uses qconf
   ./configure --prefix=/usr --qtdir=/usr ${myconf} || die "configure failed"
   eqmake4
}


qbittorrent-torrent-creator-tool.patch

Code: Select all

diff -urN qbittorrent-2.9.2/src/torrentcreator/createtorrent.ui work/qbittorrent-2.9.2/src/torrentcreator/createtorrent.ui
--- qbittorrent-2.9.2/src/torrentcreator/createtorrent.ui   2011-10-29 03:38:54.000000000 -0400
+++ work/qbittorrent-2.9.2/src/torrentcreator/createtorrent.ui   2011-11-12 16:46:50.435823724 -0500
@@ -202,6 +202,16 @@
          <string>4 MiB</string>
         </property>
        </item>
+     <item>
+        <property name="text">
+         <string>8 MiB</string>
+        </property>
+       </item>
+     <item>
+        <property name="text">
+         <string>16 MiB</string>
+        </property>
+       </item>
       </widget>
      </item>
      <item>
diff -urN qbittorrent-2.9.2/src/torrentcreator/torrentcreatordlg.cpp work/qbittorrent-2.9.2/src/torrentcreator/torrentcreatordlg.cpp
--- qbittorrent-2.9.2/src/torrentcreator/torrentcreatordlg.cpp   2011-10-29 03:38:54.000000000 -0400
+++ work/qbittorrent-2.9.2/src/torrentcreator/torrentcreatordlg.cpp   2011-11-12 16:49:36.371913350 -0500
@@ -57,7 +57,7 @@
   showProgressBar(false);
   loadTrackerList();
   // Piece sizes
-  m_piece_sizes << 32 << 64 << 128 << 256 << 512 << 1024 << 2048 << 4096;
+  m_piece_sizes << 32 << 64 << 128 << 256 << 512 << 1024 << 2048 << 4096 << 8192 << 16384;
   loadSettings();
   show();
 }